@Gabriel samaila

The first argument to your dsolve command should be sys1, not dsys. Otherwise, there was no point in creating sys1, right? As the warning message says, you can also use the parameters option. That would let you specify the value of the parameters after running the dsolve command.

Why do you want to use Runge-Kutta 4 specifically? There are newer, better methods. These newer methods select and vary the stepsize automatically, basing their choices on getting the absolute and relative errors below certain user-specifed tolerances.

Any number of plots of the same dimensionality can be combined with plots:-display, for example:

plots:-display(
   [
      Statistics:-Histogram(
         Statistics:-Sample(Normal(0,1), 9^5),
         color= aquamarine
      ),
      plot(exp(-z^2/2)/sqrt(2*Pi), z= -4..4, thickness= 5)
   ],
   title= "       The standard normal curve"
);

Notice that options that apply to individual plots (such as thickness= 5) go with the individual plot commands, and options that you want to apply globally (such as title) come after the individual plot commands.

Any Maple plotting command creates a data structure that can be assigned to a variable or manipulated otherwise. So the above could also be done like this:

P1:= Statistics:-Histogram(Statistics:-Sample(Normal(0,1), 9^5), color= aquamarine):
P2:= plot(exp(-z^2/2)/sqrt(2*Pi), z= -4..4, thickness= 5):
plots:-display([P1,P2], title= "       The standard normal curve");

These things are better done in Maple without using for. Anyway, we've shown you several for loops by now, so I think that you should be able to come up with something on your own. Here's my solution for the first problem:

Insert:= (x, pos::And(posint, satisfies(n-> n < nops(L)+2)), L::list)->
   [L[..pos-1][], x, L[pos..][]]
:

If you're studying computer science, you should learn that changing lists is inherently inefficient when you need to shift large numbers of list elements to new positions. And if you're studying Maple specifically, you should learn that it's especially inefficient in Maple, and that Maple offers other indexable order-preserving container structures (such as Vectors and tables) that are more efficient when those structures need frequent updates.

The answer is that you simply use F inside P. I removed the evalf, which only complicates things and makes them more difficult to debug. Other than the evalf, your code is equivalent (unless I messed something up) to this:

lambda:= .2:                              
mu:= .3:
                              
F:= n-> exp(-lambda*t)*(lambda*t)^n/n!:

P:= proc(n) 
local ret:= F(0), i; 
   for i to n do
      if i = 1 then ret:= ret + (diff(F(0),t)+lambda*F(0))/mu
      elif i < n then ret:= ret + (diff(F(n-1), t) + (lambda+mu)*F(n-1) - lambda*F(n-2))/mu
      else ret:= ret - (diff(F(n),t) - lambda*F(n-1))/mu
      end if
   end do;
   ret
end proc:

To test that, it'll help if you don't assign the values of lambda and mu. Let them remain symbolic.

But, I think that you made a mistake in P. It bothers me that the code after elif i < n does not depend on i. I think that you meant in that line F(i-1) and F(i-2). I can incorporate that change into a further simplified procedure:

restart:
#Leave lambda and mu unassigned for testing.
#lambda:= .2:                              
#mu:= .3: 
                             
F:= n-> exp(-lambda*t)*(lambda*t)^n/n!:

P2:= (n::nonnegint)-> 
  (`if`(n > 0, diff(F(0),t)+lambda*F(0), 0) +
   add(diff(F(i),t) + (lambda+mu)*F(i) - lambda*F(i-1), i= 1..n-2) -
   `if`(n > 1, diff(F(n),t) - lambda*F(n-1), 0)
   )/mu +
   F(0)
: 

Please test that. P2 is my replacement for your P.

My favorite way to do this uses irem. If n and d are positive integers, then irem(n, d, 'q') returns the remainder from dividing n by d and stores the quotient in q. So, my procedure is

Bin:= proc(n::posint)
local q:= n, bit, k, i;
   for k while q <> 0 do
      bit[k]:= irem(q, 2, 'q')
   od;
   [seq(bit[i], i= 1..k-1)]
end proc: 

The order that the bits are returned by this may seem backwards to you; however, this is the order that's most convenient for most subsequent computational uses. If you want the other order, simply change bit[i] to bit[k-i] in the last line of the procedure.

Here's a simple way to construct your matrices, multiply them, and force through the explicit multiplication of parenthesized factors:

n:= 6: # order of matrix
# exp(I*z) = cos(z) + I*sin(z)
A:= Matrix(n$2, (i,j)-> exp((1-i)*(j-1)*2*Pi*I/n)); 
expand~(A.A^*);

Notes (some of which were covered by others above):

• # indicates the beginning of a comment, which continues to the end of the line.
• sqrt(-1) in Maple is I, not i, unless you change that default with interface(imaginaryunit= ...).
• For a matrix A, the conjugate transpose is A^*. Since your matrix is symmetric, it's effectively just the conjugate.
• The expand command forces through the multiplication of parenthesized factors.
• For any operation OP that you want to apply to the elements of a matrix M, you can make the operation apply to all the elements by OP~(M).
• One of the most important identities in all of mathematics is exp(I*z) = cos(z) + I*sin(z). This doesn't change your matrix at all; it merely simplifies how you input it.

You can upload a worksheet to this website by using the green up-arrow on the tool bar of the editor. Nearly all of us who answer questions here prefer this to (or in addition to) screenshots because that way we don't need to retype your input into Maple.

In the general case that the Vs are arbitrary functions (expressions in a single-variable x, or constants), you can use piecewise as in

plot(piecewise(seq([x < L[k], V[k]][], k= 1..numelems(L))), x= 0..L[-1]);

If the Vs are just line segments or just constants (as in your example), then a more-efficient solution is possible, if you care, although the piecewise solution is not notably inefficient.

Note that I'm simply using the plot command; plots[multiple] isn't needed, or desired, for this.

Of course, my command above assumes that

1. L and V are indexable structures with the same number of elements and indices starting at 1 (such as Vectors or lists);
2. the Ls are distinct positive constants sorted in increasing order;
3. you wish the domain to start at x=0.

If any of those are not true, my command can be adjusted to accomodate that.

In addition to what Acer said, which is totally correct, I thought that I might give a more-thorough answer to the "How?" question that you directly posed at the end of your Question. Take a look at this simple recursive code, which is what's ultimately executed by your convert command:

showstat(`convert/list`::convert_rtable_to_nested_list);

You'll see that there's no magic efficiencies, no special provisions for sparsity, no special provisions for order, and no special handling of zeros. It's just a recursive loop whose base case is simple indexing, as in A[...].

Integration with respect to functions as opposed to with respect to simple variables is not something handled by int (well, at least not in its common usage). If you assign expressions to x and y, then you can't integrate with respect to x or y.

Most packages are implemented as modules. Anything that can be accessed in the form A:-B comes from a module named A. Modules have two types of local variables: regular (private) locals and (public) exports. Ordinarily, only exports can be accessed with the :- operator. But, if you issue

kernelopts(opaquemodules= false);

then you'll be able to access private locals also.

Another way to see module A's local procedure B is

showstat(A::B);

This was only implemented a few versions ago, so I don't know if you have it. Regardless, the opaquemodules trick will definitely work.

Note that it's ithratB, not ithratb. Also, showstat(ithratB) will never work. It either has to be showstat(numtheory:-ithratB) or showstat(numtheory::ithratB) (or <*cringe*> showstat(numtheory[ithratB]) (*footnote)). Dropping the module-name prefix is only allowed for exports and then only in the context of a with or use command or a uses clause.

(*footnote): The use of the syntax A[B] as a general substitute for A:-B is something that I strongly disdain. The A:-B is precise: It can only mean that B is literally and explicitly, without any further evaluation, a local or export of module A. The syntax A[B] can mean a great many things and even if it's known that A is a module, it's B's evaluated value that gets looked up. The A[B] is only acceptable to me when B needs to be evaluated first. Unfortunately the Maple documentation is loaded with the inappropriate use of this syntax.

Something that I occasionally find useful along these lines is kernelopts(memusage). It returns a listlist (which, oddly, displays as a Matrix---I guess kernelopts has special privileges of display?) of three columns: The first is labels for 63 categories of possible objects stored in memory, the second is the number of objects stored in each of those categories, and the third is the number of bytes stored in each of those categories. So, you can call it before and after calling a suspect procedure and take the difference of the two readings.

I believe---but I'm not sure---that this command gives you a true partition of all stored data, i.e., every byte of data that you currently have stored appears in exactly one of the 63 categories.

Two things needed: 

1. Replace U and V with U(x,t) and V(x,t) throughout pde1 and pde2.
2. The first argument to pdsolve should be {pde1, pde2}.

These are necessary to solve your problem but not necessarily sufficient. I can't get on my computer right now to check. (There's a "no laptops" sticker on the café table I'm at.)

How do you expect n! to be defined for negative integers n other than by extension to GAMMA?

I think that Maple is primarily designed for high and wide computational power rather than to be educational or didactic. That requires that most functions be defined over the largest part of C possible. But, you can restrict the domains using assuming. In this case, you should append assuming n::posint to the original product. The resulting formula will contain GAMMA functions, but it'll evaluate correctly for your range of n regardless of whether you convert to factorial.

It seems that your attempt to upload the worksheet didn't work. Could you try again please?

Are you trying x[1] or x__1 for the variable? If it's either of those, it's surely the first. And did you tell it the name stem that you wanted to use? In that case, tell it to use :-x (colon hyphen x). Or did you let it choose the name stem? Then it must be _x[1]. Unassigned global names that library procedures generate for output always begin with underscore.

x[1] is a name with an index subscript; x__1 is a name with an inert subscript. They display the same (as subscripts) in pretty-printed output.

If you have output that you don't understand how to type, often applying the command lprint to that output improves understanding:

lprint(%);

Use expand rather than simplify. That's just being specific about the type of simplification that you want.