Here's a solution for an arbitrary number of dancers, using evenly spaced points on the unit circle as the starting points. The ODEs are essentially the same as in my solution above. I decided to form the dependent variable names with indexing (x[1], x[2], y[1], etc.) rather than with cat and ||. I also changed the indexing from 0..n-1 to 1..n. The brevity of the code shows Maple's great power at forming and working with a repetitive set of ODEs.

restart:
SpiralDance:= proc(n::posint)
local
     k, K:= k= 1..n, x, y, V_k:= [x[k],y[k]], v,
     eqns:= seq(((D+(X->X))(v[k]) = v[1+irem(k,n)]) $ K, v= [x,y]),
     ics:= op~([(V_k =~ [cos,sin](-2*k*Pi/n)) $ K])[],
     t, Sol:= dsolve({eqns(t),ics(0)}, numeric)
;
     plots:-odeplot(Sol, [V_k(t) $ K], thickness= 3, axes= none, gridlines= false)
end proc:

SpiralDance(5);

The breakpoint command in Maple is stopat. See ?stopat.

Your transform is (x,y)-> [x-y]. This says "take a point (x,y) on the graph and replace it with the single number x-y." That makes no sense: You need to replace points with points---pairs of numbers---not with single numbers.

I also encourage you to replace PLOT with plots:-display. 

There's a decimal point that you included somewhere in your input. Remove it.

Here's a simple solution, off the top of my head, with the dancers starting at [1,1], [1,-1], [-1,-1], [-1,1]. I leave animating this solution to you. It's really easy. The position of dancer k (0 to 3) at time t is [x||k(t), y||k(t)].

Download Spriral_Dance.mw

Try the old profiling commands: exprofile, excallgraph, profile. I don't have much experience with profile. I've used exprofile and excallgraph a lot, and I've never come across code that they couldn't handle.

The mathematical constant Pi is spelled with a capital P in Maple. If you spell it pi, it's just another variable, which, unfortunately, prettyprints exactly the same as the mathematical constant. However, the printed forms can be distinguished using the lprint command.

A (nonconstant) function of a random variable is itself a random variable. So your Y is already a random variable and there's no need to apply RandomVariable to it. Skip T1, and do what you want with Y, such as 

simplify(PDF(Y,t));

or, more directly,

simplify(PDF(1/X,t));

Download Pivot.mw

I think that the only reason to use Join would be if you wanted to use its second argument, the separator. I did some quick tests, and cat is quicker and uses less memory. Join is externally compiled and cat is built-in, so they're both pretty efficient.

How about shifting the z-coordinates of the centers of the base circles?

p1:= plottools:-cylinder([1, 1, 1], 1, 1):
p2:= plottools:-cylinder([1, 1, 2], 2, 3):
p3:= plottools:-cylinder([1, 1, 5], 1, 4):

plots:-display([p1,p2,p3]);

Here's an example of your 1, 2, and 3. There are many ways for 2 and 3. Pay special attention to the way that prime-power fields are created in Maple because it's a little unusual.

restart:
#0. Create the matrix
p:= Randprime(3,x) mod 2;
alias(x= RootOf(p,x)):
M:= Matrix(5,7, ()-> randpoly(x, degree= 3));

#1. Get the rank.
Gausselim(M, 'rank') mod 2:
rank;
     5

#2. Row sum squared
V:= Vector(op([1,1], M), i-> expand(add(y, y= M[i,..])^2));

#3. Dividing by row sum squared
Matrix(op(1,M), (i,j)-> M[i,j]/V[i]);

See the commands ?sign, ?primpart, and ?content. Using those, here's a short procedure for it:

p:=x^2*y-2*y*z+3*x^2+2*y-z:

RepeatPositiveTerms:= (P::polynom(integer))->
     [seq(`if`(sign(t)=1, primpart(t) $ content(t), [][]), t= [op(expand(P))])]
:

RepeatPositiveTerms(p);

     [x^2*y, x^2, x^2, x^2, y, y]

Any function can be made to map over a list by appending ~ to its name:

abs~(L);
signum~(L);

Or, getting a bit fancier, there's

(abs~, signum~)(L);

Your system is overspecified: You have three equations, but only two unknown functions. This can't be solved.