I think that you are saying that you want the various orderings of the compositions to be considered as one for the purpose of random selection. Then you want to use partition instead of composition, like this:

RandomPartitions:= proc(n::posint, k::posint)
local
     C,
     Partitions:= [seq(C-~1, C= select(p-> nops(p)=k, combinat:-partition(n+k,n+1)))],
     Rand:= rand(1..nops(Partitions))
;
     ()-> Partitions[Rand()]
end proc:

R:= RandomPartitions(8,6):
n:= 1000:
map(lhs=rhs/n, Statistics:-Tally(['R()[]' $ n]));

Unfortunately, "approximate using n digits precision" means that the subcomputations are done to n digits, not that the overall computation is accurate to n digits. It is the responsibility of the user to increase the precision of the subcomputations if that is needed.

Your code is selecting the second point of the two returned by solve. Apparently, you want the first point. So, you need a criterion with which to select between the two points returned by solve. Would the point which is closest to the origin be an appropriate criterion? Then you can use this procedure.

Closest:= proc(
     Sol::list(list(name=numeric)),
     {To::list(numeric):= [0,0],
      XY::list(name):= ['x', 'y']
})
local
     Min:= infinity, ptMin, pt, d,
     dist:= proc(Pt1,Pt2)
     option inline;
          evalf(sqrt(`+`(((Pt1 -~ Pt2)^~2)[])))
     end proc
;
     for pt in Sol do
          d:= dist(eval(XY, pt), To);
          if d < Min then
               Min:= d;
               ptMin:= pt
          end if
     end do;
     
     ptMin
end proc: 

Pt:= Closest(Sol);

Point2:= plottools:-disk(eval([x,y], Pt), 0.2e-1, color = red):

How about this?

n:= 10:
map(lhs=rhs/n, Tally(['R()[]' $ n]));

seq(coeff(eq,v), v= vars);

Using ex as your original expression,

subsop(1= factor(op(1, ex)), ex);

convert(expand(u^3+u^2-1), exp);

There are numerous problems in your code. First, the inverse tangent function is arctan, not atan. Second, you cannot make an assignment inside a return statement (or any other statement). Unlike C, in Maple an assignment is not an expression that can be part of another expression. Third, what's the point of having a loop if you're always going to return on the first iteration?

Correct these and then maybe we can discuss the rest.

I was able to get a result by substantially reducing the requested accuracy. I had to increase abserr, but not relerr. So, I'm a bit skeptical about this result. I changed your theta to T to save typing.

restart:
ODE:=
     (1+T(x))*diff(T(x),x) + x*diff(T(x),x)^2 +
     x*(1+T(x))*diff(T(x),x$2) - T(x)^3-diff(T(x), x)
     = 0
;

BCs:= T(1)=1, D(T)(0) = 0:
Sol:= dsolve(
     {ODE, BCs}, numeric, method= bvp[middefer],
     maxmesh= 2^15, abserr= .58e-1
):
plots:-odeplot(Sol, [x,T(x)], x= 0..1);

subs is a low-level command that can only be used to substitute for subexpressions that appear as nodes on the tree that represents the expression. So using subs requires some (small) amount of knowledge of how expressions are stored. For example, in the expression x+y+z, the nodes are x+y+z, x, y, and z; x+y is not a node. You can see the tree representing an expression by using ToInert(expression). Unfortunately, the representation is not graphical.

algsubs is a high-level command that can be used to substitute for more-complicated subexpressions. The syntax is the same as subs. In your case, that would be

algsubs(cosh(k*h)/sinh(k*h)= 1/tanh(k*h), td);

If tangent lines are perpendicular, then their corresponding radii are perpendicular.  Given three points A, B, C, then AB is perpendicular to BC iff (A[2]-B[2])*(C[2]-B[2]) = (B[1]-A[1])*(C[1]-B[1]).

I also vastly simplified the rest of your code, mostly by using isolve to get the integer points on the circle.

Download Nonperpendicular.mw

Let the expression be expr. Then do

op(indets(expr, specfunc(anything, RootOf))[1]);

Yes, it is easy with plotsetup(window). See help pages ?plot,device and ?plotsetup .

Your question is barely readable. In the future, enter your matrix into Maple and then cut-and-paste the matrix into your post.

I hope that you can draw your conclusions from the following worksheet. If not, ask for more help.

Download Parametric_linear_system.mw

Download Linear_system.mw