psi:=u(x,y,t)+I*v(x,y,t):

evalc(diff(psi,t)*I+diff(psi,x,x)=epsilon*diff(evalc(abs(psi)^2),y,y)*psi);

evalc~([(Re,Im)~(%)]);  # This is your desired system

Edited.

You can display it as follows:

aa1:=``(f(x+Dx,y+Dy)-f(x,y+Dy)) - ``(f(x,y)-f(x,y+Dy));

Obviously that in real domain the system of three equations  {pd1=0, pd2=0, pd3=0}  is equivalent to the single equation  pd1^2+ pd2^2+ pd3^2=0

restart;

AllGraphs:=proc(n::posint)

local V, S;

uses combinat, GraphTheory;

V:={$1..n};

choose(V,2);

S:=powerset(%);

[seq(Graph(n,s), s=S)];

end proc:

Examples of use:

AllGraphs(3);

plots[display](Matrix(2,4, GraphTheory[DrawGraph]~(%)));

or

AllGraphs(4);

plots[display](Matrix(8,8, GraphTheory[DrawGraph]~(%)));

F:=(d^4-2)*C+(7*d^3-3*d)*C^2-(10*d^4-4*d)*L^2+(d-d^2)*L^3+(R+z^2)*x1+(10*d^3-4*d)*L:

F:=coeff(F,C)*C+coeff(F,L)*L+coeff(F,x1)*x1;

                                          F := (d^4-2)*C+(10*d^3-4*d)*L+(z^2+R)*x1

or more automatically

restart;

F:=(d^4-2)*C+(7*d^3-3*d)*C^2-(10*d^4-4*d)*L^2+(d-d^2)*L^3+(R+z^2)*x1+(10*d^3-4*d)*L:

V:=<C,L,x1>:

F:=add(coeff(F,v)*v, v=V);

Because the function has circular symmetry, it is natural to immediately use the polar coordinates:

int(int(Heaviside(1-r^2)*r, r=0..1), phi=0..2*Pi);

                                      Pi

This calculation can be easily done by hand (without Maple).

Student[Basics][ExpandSteps](factor(x^4+4));

You have to read from the bottom up.

display(fig1, plot(eval(Model, MinSol[2]), x = 0 .. 1.5, color = red, thickness = 0));

You can generate a random function of a certain class of functions depending on a finite number of parameters.

Example: a random function of the class  a*sin(b*x+c)  in which  [a,b,c]  is a random list of floats with the uniform distribution in the range  0..10 :

RandomTools[Generate](list(float(range=0...10, method=uniform), 3));

eval(a*sin(b*x+c), [a,b,c]=~%);

Should be  D(x)(0)  instead of  D(x) (0)

A space between  D(x)  and  (0)  Maple interprets as a multiplication.

For any real numbers b>0, c>0  the expression sqrt(sqrt(9)*sqrt((1+(b+1)^2*c^2+((10/3)*b-2)*c)*(1+(b+1)^2*c^2+(2*b-2)*c))+3+(3*b^2+6*b+3)*c^2+(8*b-6)*c)  will be strictly positive . Here is the simple solution (in fact by hand):

u:=sqrt(sqrt(9)*sqrt((1+(b+1)^2*c^2+((10/3)*b-2)*c)*(1+(b+1)^2*c^2+(2*b-2)*c))+3+(3*b^2+6*b+3)*c^2+(8*b-6)*c);  # The original expression

v:=normal(u^2);  # The simplified expression under the square root

v1:=3*b^2*c^2+6*b*c^2+3^(1/2)*((3*b^2*c^2+6*b*c^2+10*b*c+3*(c-1)^2)*(b^2*c^2+2*b*c^2+2*b*c+(c-1)^2))^(1/2)+8*c*b+3*(c-1)^2;  # In  v  we substitute c^2-2*c+1=(c-1)^2  # All terms are strictly positive if  c<>1, c>0, b>0

eval(v1, c=1);  # for c=1

If the parameters  beta, gamma, R4 and C2  are not necessarily positive, vv's solution does not work. Assume  command helps in this case. Also I wrote  local gamma;  because  gamma is protected constant (Euler's constant).

restart;

local gamma;

assume(gamma>0,beta<0,R4>0,C2<0):

f:=gamma*sqrt(4)*sqrt(omega^2*C2^2*R4^2/(C2^4*R4^4*beta^2*gamma^2*omega^4+C2^2*(1+gamma^2*(beta+1)^2-2*gamma)*R4^2*omega^2+1)):

diff(f,omega):

solve(%=0, omega);

select(t->is(t>0),[%])[];

I think the reason is a low accuracy of calculations (10 digits), while the coefficients of the polynomial specified with high precision. I set  Digits:=100  and use  fsolve  command, which finds all real roots for polynomials:

Digits:=100:

P:=-12116320194738194778134937600000000*t^26+167589596741213731838990745600000000*t^24+1058345691529498270472972795904000000*t^22-4276605572538658673086219419648000000*t^20-23240154739806540070988490473472000000*t^18-5442849111209103187871341215744000000*t^16+49009931453396028716875310432256000000*t^14+74247033158233643322704589225984000000*t^12-2762178990802317464801412907008000000*t^10-25947900993773120244883450232832000000*t^8-7468990043547273070742668836864000000*t^6-567730116675454293925108383744000000*t^4+3703566799705707258760396800000000*t^2-4742330812072533924249600000000:

Sol:=fsolve(P):

seq(eval(P,t=s),s=[Sol]);  # Check

-.25965814962389295505e-49, -.39367217335124e-55, -.4842468019e-59, .1022039e-62, -.1e-68, 0., 0., -.1e-68, .1022039e-62, -.4842468019e-59, -.39367217335124e-55, -.25965814962389295505e-49

Vic, Carl gave a solution for a matrix with 2 parameters  a  and  d .  The following procedure  named  Tr  solves your problem for any number of parameters. The procedure returns the sequence of 2^N  matrices, where  N is the number of parameters :

Tr:=proc(n,s)

local A, S, N;

A:=Matrix(n, s, shape=antisymmetric);

S:=indets(s);

N:=nops(S);

seq(eval(A,S=~p), p=combinat[permute]([-1$N,1$N],N));

end proc:

Examples of use.

The first one is yours:

s:={(1,3)=a,(1,4)=-a,(1,5)=-d,(1,6)=d,(2,4)=-d,(2,5)=d,(2,6)=-d,(2,7)=d,(3,5)=a,(3,6)=d,(3,7)=-d,(4,6)=-d,(4,7)=-a,(5,7)=a}:

Tr(7,s);

Tr(7,s)[1]  is the first matrix in this sequence and so on.

The second example solves the same problem if we have 3 parameters  a , d , e :

s:={(1,3)=a,(1,4)=-a,(1,5)=-d,(2,4)=-d,(2,5)=e}:

Tr(5,s);

This equation you can solve only numerically. Here is the least positive root:

fsolve(2*x-tan(x), x=0..Pi/2, avoid={x=0});

                                        1.165561185