To find a solution I have arbitrarily given initial conditions:

restart;

w:=1+t/100:

dsolve({diff(x(t),t$2)+w^2*x(t)=0, x(0)=1, D(x)(0)=2}, x(t)):

x:=unapply(rhs(%), t):

y:=unapply(diff(x(t),t), t):

plot([x,y], 0..10, color=[red,blue], thickness=2, legend=['x(t)','y(t)']);

If I understand your question then

A:= .5464691235-.4473247264*I, -.4563184747+1.*10^(-14)*I, .5464691235+.4473247264*I:

 Re(sort([A], (z1,z2)->abs(Im(z1))<abs(Im(z2)))[1]);

                                                    -0.4563184747

Secant := proc (f::procedure, x1::realcons, x2::realcons)

local A, B, C, a, b, d;

a, b := `if`(is(x1<x2), op([x1,x2]), op([x2,x1]));

d := b-a;

A := plot(f, a-(1/5)*d .. b+(1/5)*d, color = blue, thickness = 2);

B := plot(f(a)+(f(b)-f(a))*(x-a)/(b-a), x = a-(1/5)*d .. b+(1/5)*d, color = green, thickness = 2);

C := plot([[a, f(a)], [b, f(b)]], style = point, symbol = solidcircle, symbolsize = 17, color = red);

print(y = f(a)+(f(b)-f(a))*(x-a)/(b-a));

plots:-display(A, B, C, gridlines);

end proc:

Example:

Secant(x->x^2, -1, 2);

restart;

A:=plot(x^2, x=-2.5..2.5, color=blue, thickness=2):

B:=plot([[1,1],[2,4]], style=point, symbol=solidcircle, color=red, symbolsize=17):

plots[display](A,B, scaling=constrained, gridlines);

Edited.

This particular problem can be solved in Maple by simple enumeration  on the set of all partitions of the original set of 8 golfers:

S:=combinat[setpartition]({$ 1..8}, 2):

S1:={S[1]}: n:=nops(S):

print(S[1]);

for i from 2 to n do

S2:=op(S1);

if `intersect`(S[i], `union`(S2))={} then

S1:={S2,S[i]}; print(S[i]) fi;

od:

Edited.

Example:

A:=Matrix(10, (i,j)->evalf(sin(i*j)^2)):

plots[matrixplot](A, axes=boxed);

In fact, you have a system of algebraic equations rather than of differential equations (no derivatives). Therefore, decide it by solve  command in real domain:

RealDomain[solve]({a^2*b=-7, a=3*b}, {a,b});

In such examples, I usually use the commands from the packages plots and plottools, as the syntax will be shorter :

restart;

sys := [x-2*y+z = 0, 2*y-8*z = 8, -4*x+5*y+9*z = -9]:

P := rhs~(op(solve(sys, [x, y, z])));  #Coordinates of the point of intersection

A := plots[implicitplot3d](sys, op([x, y, z]=~[seq(P[i]-5 .. P[i]+5, i = 1 .. 3)]), color = [blue, green, yellow]):  # Three planes

B := plottools[sphere]([op(P)], 0.3, color = red):  # The point of intersection as a small red sphere

plots[display](A, B);  # All together

There are many ways to do it. Here's one simple way:

P:=N->combinat[permute]([0$N, 1$N], N):

Example of use:

P(3);

           [[0, 0, 0], [0, 0, 1], [0, 1, 0], [0, 1, 1], [1, 0, 0], [1, 0, 1], [1, 1, 0], [1, 1, 1]]

One way:

restart; 

L:=[ [ [1,2], [2,1] ], [ [3,4], [4,3] ], [ [5] ] ]:

n:=0:

for i in L[1] do

for j in L[2] do

for k in L[3] do

n:=n+1: P[n]:=[op(i), op(j), op(k)]

od: od: od:

convert(P, list);

                    [[1, 2, 3, 4, 5], [1, 2, 4, 3, 5], [2, 1, 3, 4, 5], [2, 1, 4, 3, 5]]

Another more general way:

restart;

L:=[ [ [1,2], [2,1] ], [ [3,4], [4,3] ], [ [5] ] ]:

T:=combinat[cartprod](L):

n:=0:

while not T[finished]  do n:=n+1; P[n]:=op~(T[nextvalue]()) end do:

convert(P, list);                     

                       [[1, 2, 3, 4, 5], [1, 2, 4, 3, 5], [2, 1, 3, 4, 5], [2, 1, 4, 3, 5]]

Edited. 

An example:

P:=a*b^2 + b*c - a^3*c^2;

Q:=expand(P^7);

ind:=indets(%);

n:=igcd(seq(degree(Q,s), s=ind));

RealDomain[simplify](Q^(1/n), symbolic);

The example:

V:=Vector([x+y=1, x-y=2]);

A, v:=LinearAlgebra[GenerateMatrix](convert(V, list), [x,y]);  #  A is the matrix, v is the vector

<A | v>;   #  augmented matrix of the system

assume(a<>1, a*c<>1):

 is(a^2*c-a*c-a+1<>0);

                   true

Your function has an infinite number of points of inflection. To find them within a given range, we can use  RootFinding[Analytic]  command. I took the range  -5..5 .

f := x->(7-x)*sin(x^2-7):

F := diff(f(x), x, x);

L := [RootFinding[Analytic](F, re = -5 .. 5, im = -0.1 .. 0.1)];

P := map(t->[t, f(t)], L);

Visualization:

A := plot(P, style = point, symbol = solidcircle, color = red):

B := plot(f, -5 .. 5, color = blue):

plots[display](A, B);

Probably there is no need for such a large number of Digits. I left 5 digits, the expression converted to the fraction and simplified by  normal  command:

A:=2.560000000*10^(-30)*k1*(2.309486127*10^38*n-1.154743064*10^38-1.186994552*10^37*k2^2*n^2+2.373989104*10^37*k2^2*n+8.541613702*10^37*k2*n^2-1.154743064*10^38*n^2+7.119519043*10^37*n^2*k1^2+6.495962587*10^37*k1*n^2-1.293058266*10^38*k2*n^2*k1-1.186994552*10^37*k2^2-1.708322740*10^38*k2*n+1.293058266*10^38*k2*n*k1+8.541613702*10^37*k2-3.529088273*10^37*k1-2.966874313*10^37*k1*n)/(1.620847396*10^9*n-1.620847396*10^9):

normal(convert(evalf[5](A), fraction));

If you want to keep all the digits, just

normal(convert(A, fraction));