restart;
  with(plots):
#
# This animation will work even although, for x=0,
# the embedded plot command has zero range, when x=0
#
  animate(plot, [sin(t), t=0..x], x=0..3 );
#
# However the following will fail with an error if the
# lower limit of the x-range is set to zero. Looks like
# the odeplot() command can't handle a range of zero,
# unlike the plot command above
#
# So this will work
#
  dsol := dsolve({diff(y(t),t) = -y(t), y(0)=1}, numeric):
  animate(odeplot, [dsol, [t,y(t)], t=0..x], x=1e-06..3 );
#
# But this won't :-(
#
  animate(odeplot, [dsol, [t,y(t)], t=0..x], x=0..3 );

Error, (in plots/animate) invalid range

with(plots):
with(plottools):
p1:=polygon( [ [ 0, 0], [0,1], [1,1], [1,0.75],[0.25, 0.75], [0.25, 0.25],[1.0, 0.25], [1.0,0] ]):
display(p1);
p2:=polygon( [ [ 0, 0], [0,1], [1,1], [1,0.75],[-0.25, 0.75], [-0.25, 0.25],[1.0, 0.25], [1.0,0] ]):
display(p2);

  restart:
  declare (f(x),g(x),t(x),prime=x):
  L:=5:R:=0.5:M:=5:K:=5:
#
# Notice that in each of the following defnitions
# simplification means that all terms involving 'p'
# disappear before values for f(x), t(x), g(x) are
# substituted - so why are these terms here in the
# first place???
#
  H01:= simplify
        ( (1-p)*(1+K)*diff(f(x),x,x)+p*(1+K)*diff(f(x),x,x)+K*diff(g(x),x)+t(x)-M*f(x)
        );
  H02:= simplify
        ( (1-p)*(1+(K/2))*diff(g(x),x,x)+p*(1+(K/2))*diff(g(x),x,x)-K*diff(f(x),x)-K*2*g(x)
        );
  H03:= simplify
        ( (1-p)*diff(t(x),x,x)+p*diff(t(x),x,x)
        );

  f(x):=sum((p^i)*f[i](x),i=0..L):
  g(x):=sum((p^i)*g[i](x),i=0..L):
  t(x):=sum((p^i)*t[i](x),i=0..L):
#
# Since terms involving 'p' disappeared earlier,
# H01, H02, H03, will only contain powers of 'p'
# arising from the definitions of f(x), g(x), t(x)
# above, so the maximum power of 'p' will be p^L,
# as the following demonstrates
#
  H01:=collect( expand(H01), p);
  H02:=collect( expand(H02), p);
  H03:=collect( expand(H03), p);
#
# Since the maximum power of 'p' is p^L, why does
# this loop run to L+1? All this will do for i=L+1
# is generate the equation 0=0
#
# Notice also, that apart from a trivial renaming of
# functions, the *form* of every "coefficient" in
# say equa[1] is the same  - is this intentional
#
  for i from 0 to L+1 do
      equa[1][i]:=coeff(H01,p,i)=0:
      equa[2][i]:=coeff(H02,p,i)=0:
      equa[3][i]:=coeff(H03,p,i)=0
  end do:

 

restart;
expr:=sin(4*Pi*w)/sin(2*Pi*w) ;
subs(z=2*w, expand(algsubs( 2*w=z, expr)));

  restart;
  RootOf(_Z^2*beta*h[1]-alpha*l[1]*l[2], label = _L2);
#
# All values of the above expresssion in easily(?)
# accessible form
#
  ans:=[allvalues(%)];
  ans[1];
  ans[2];

  with(plots):
  p1:= implicitplot3d( [x^2+y^2+z^2=1, x+y+z=0],x=-1..1, y=-1..1, z=-1..1, color=[red,blue], style=surface, transparency=0.5):
  p2:= intersectplot(x^2+y^2+z^2=1, x+y+z=0, x=-1..1, y=-1..1, z=-1..1, color=green, thickness=4):
  display([p1,p2]);

  with(ScientificConstants):
#
# function to return the atomic weight of an element.
# The returned value is in units of 'amu'
#
  gtWeight:= x-> [ x,
                   rhs
                   ( rhs
                     ( GetElement
                       ( x, atomicweight )[2]
                     )[1]
                   )
                 ]:
#
# Return the atomic weight of (say) carbon
#
  gtWeight('C');
#
# Return the atomic weights of the first 12 elements
#
  elems:=[H, He, Li, Be, B, C, N, O, F, Ne, Na, Mg]:
  gtWeight~(elems);

  restart;
  with(plots):
#
# Illustrate OP's problem - the third plot is "wrong"
#
  expr:=[-x/(x^2+y^2)^1.5,-y/(x^2+y^2)^1.5]:
  fieldplot( expr,
             x = -1..1,
             y = -1..1,
             arrows=thick
           );
  fieldplot( expr,
             x = -1..1,
             y = -1..1,
             grid=[8,8],
             arrows=thick
           );
  fieldplot( expr,
             x = -1..1,
             y = -1..1,
             grid=[7,7],
             arrows=thick
           );

#
# So what is happening??
#
# If one calculates the grid points and the field components
# explicitly for various grid sizes (all with n odd) and then
# selects the "one in the middle", which *ought* to correspond
# to x=0,y=0, where the vector field is undefined, one gets
# the following
#
  seq
  ( [ n,[ seq
          ( seq
            ( [x, y, expr],
              y=-1..1, evalf(2/(n-1))
            ),
            x=-1..1, evalf(2/(n-1))
          )
        ][floor(n^2/2+1)][]
    ],
    n=3..13, 2
  );

#
# In the above command, the floating-point calculation does
# produce [0,0] as a grid point for all grid sizes, other than
# n=7. When the grid point is *exactly* [0, 0], then the value
# of the vector field is [Float(undefined), Float(undefined)].
#
# However when n=7, rather than using the grid point [0, 0], the
# calculated grid point is at [-1.*10^(-10), -1.*10^(-10)], where
# the field is defined (but huge)
#
# The default for fieldplot() is to illustrate field strength
# with the *relative* drawn length of the arrows. The computed
# field strength at [-1.*10^(-10), -1.*10^(-10)] is so huge
# that the "relative" length of the arrows at all other grid
# points is essentially zero, and cannot be seen in the plot
#

#################################################################
#
# Workaround, define a "tolerance" around [0,0], within which
# the field strength is delared as undefined
#
  tol:= 1e-06:
  func1:= (p, q)->`if`( `and`( abs(p) < tol,
                               abs(q) < tol
                             ),
                        Float(undefined),
                        eval( expr[1], [x=p, y=q] )
                     ):
  func2:= (p, q)->`if`( `and`( abs(p) < tol,
                               abs(q) < tol
                             ),
                        Float(undefined),
                        eval( expr[2], [x=p, y=q] )
                      ):
#
# Now fieldplots work "correctly"
#
  fieldplot( [ func1,func2 ],
             x = -1..1,
             y = -1..1,
             arrows = thick
           );
  fieldplot( [ func1, func2 ],
             x = -1..1,
             y = -1..1,
             grid = [8,8],
             arrows = thick
           );
  fieldplot( [ func1, func2 ],
             x = -1..1,
             y = -1..1,
             grid = [7,7],
             arrows = thick
           );
                    

  restart;
  interface(version);
  with(StringTools):
#
# NB the string in the following is cut+paste from
# OP's worksheet in order to "preserve" any weird
# (eg non-printing?) characters
#
  a:="Microsoft_Edge_‎08_‎29_‎2019.html";
#
# and yes, Reverse() goes nuts!
#
  Reverse(a);
#
# Filter out non-ASCII characters
#
  b:=Implode(select( IsASCII, Explode(a)));;
#
# Now Reverse() works
#
  Reverse(b);

combine(20*Unit(Celsius)+30*Unit(K),units);

convert(20*Unit(Celsius,preserve),temperature, kelvin)+ 30*Unit(K);
evalf(%);
20*Unit(Celsius)+convert(30*Unit(kelvin, preserve), temperature,Celsius);
evalf(%);

is( -1*Unit(Celsius)=-1*Unit(Fahrenheit));
is( 0*Unit(Celsius)=0*Unit(Fahrenheit));
is( 1*Unit(Celsius)=1*Unit(Fahrenheit));

restart:
kernelopts(version);
interface(prettyprint);
lprint(<1,2;3,4>);

Matrix(2,2,{(1, 1) = 1, (1, 2) = 2, (2, 1) = 3, (2, 2) = 4},datatype = anything
,storage = rectangular,order = Fortran_order,shape = [])

Matrix(2,2,{(1, 1) = 1, (1, 2) = 2, (2, 1) = 3, (2, 2) = 4},datatype = anything
,storage = rectangular,order = Fortran_order,shape = []);