The problem can be solved without using inequalities:

{solve((1/(a-1)-1/(a+1))*(2*a^2-2)/a = 4/sqrt(2), a)}  minus  {-1, 1};

Rouben Rostamian Your example is not an example of  p versus w. It is the example of a parametrically given function  z->(w(z), p(z))  with  z  as a parameter. Here is the example - the plot  w->p(w)  in the range w=50000..150000 :

restart;
Sys := -(diff(p(z), z)) = 1.289*10^10*(.675+77/(Pi*1.2^2))*(1+x(z))*(1/(Pi*1.2^2*p(z))), diff(x(z), z) = (1.134*10^(-8)*Pi)*1.2^2*(1-x(z))*p(z)/(1+x(z)):
Inc := p(0) = 2*10^6, x(0) = 0:
Sol := dsolve({Inc, Sys}, numeric):
Eq := w = 1560*Pi*(9*z-(1/3)*(z-2.7)^3*((1/3)*2.7^3)):
f := t->fsolve(eval(Eq, w = t), z):
w1 := 50000: w2 := 150000:
z1 := min(f(w1), f(w2)): z2 := max(f(w1), f(w2)):
plot(rhs(Eq), z = 0 .. 7, -100000 .. 200000, labels = [z, w], labelfont = [TIMES, ROMAN, 14]);  # The plot of the function  z->w(z)
plots[odeplot](Sol, [rhs(Eq), p(z)], z = z1 .. z2, color = blue, labels = [w, p], labelfont = [TIMES, ROMAN, 14]);  # The plot of the function  w->p(w)  in the range  w=50000..150000

Of course, it is easier to solve the equation by hand, as M. Hirnyk  wrote, but if you want to solve with Maple, then there are some difficulties. Because all three terms of the equation are non-negative, then the sum is equal to 0 only if each term is equal to 0. But Maple somehow does not solve the simple system  sys . Therefore it is necessary to solve it step by step:

restart;

eq:=abs(a-b)+sqrt(2*b+c)+``(c^2-c+1/4)=0;

L:=op(lhs(eq));

sys:={L[1]=0,L[2]=0,op(L[3])=0};

solve(sys,{a,b,c});  # Incorrect solution

c0:=solve(op(L[3]))[1];  # First we solve the equation  c^2-c+1/4=0

op(solve(eval(sys,c=c0))),c=c0;  # Final answer

If I understand your question then

eval(1.18971*x^0.38480, x=17);  # Or

f:=x->1.18971*x^0.38480:

f(17);

                     3.539303919

                     3.539303919

M := proc (k::nonnegint, n::nonnegint) 

option remember;

if k = 0 or n = 0 then M(k, n) := 0 elif

k = 1 then M(k, n) := n elif

n = 1 then M(k, n) := 1 else

M(k, n) := M(k, n-1)+M(k-1, n-1)+M(k-2, n-2) end if

end proc:

Example (all values for 0<=k, n<=9):

Matrix(10, (i, j) -> M(i-1, j-1) );

 Code was edited.

To really examine your 9 graphs I removed the multiplier 100, 0 in the denominator, add the colors and change the ranges of the axes:

with(plots):

pi:=Pi:

u := sin((1/2)*pi*x)*((1-cosh(pi))*sinh((1/2)*pi*y)+sinh(pi)*cosh((1/2)*pi*y));

implicitplot([u = 10, u = 20, u = 30, u = 40, u = 50, u = 60, u = 70, u = 80, u = 90], x = -5 .. 7, y = -5 .. 7, color=[red, black, khaki, pink, yellow, blue, green, violet, gold], grid = [100, 100]);

 Edit. The set  {u = 10, u = 20, u = 30, u = 40, u = 50, u = 60, u = 70, u = 80, u = 90}  was changed to the list.

For  9 team competition in one round (round-robin tournament or all-play-all tournament)   9*8/2=36  games should be played. Here is the example of a random tournament between teams  A, B, C, E, F, G, H, K, M :

restart;

roll:=rand(0..1):

assign(seq(seq(a[i,j]=roll(),j=i+1..9),i=1..8)):

assign(seq(a[i,i]=` - `, i=1..9)):

assign(seq(seq(a[i,j]=1-a[j,i],j=1..i-1),i=2..9)):

<Vector([[``,A,B,C,E,F,G,H,K,M]])|<Matrix([[A,B,C,E,F,G,H,K,M]]),Matrix(9, (i,j)->a[i,j])>>;

Any such matrix is uniquely determined by the numbers that stand above (or below) the main diagonal. Obviously the number of the all matrices of such type is  2^36 .  If we want to write down all the possible variants in a single matrix, we get a huge matrix with  36  rows and  2^36  columns.

I think the original problem can be solved, if we go in 3-D space. We just roll up the plane in a tube (cylinder). Axis  theta goes along the circumference, and the values of the function we read from the vertical axis.

Example:

R := 1:

E := plot([cos(3*theta), 0], theta = 0 .. 2*Pi, color = [red, blue], thickness = [3, 2]):

F := plot([1, -1], theta = 0 .. 2*Pi, color = grey, filled):

plots[display](E, F, scaling = constrained);

A := plot3d([R*cos(theta), R*sin(theta), z], theta = 0 .. 2*Pi, z = -1 .. 1, style = surface, color = grey):

B := plots[spacecurve]([R*cos(theta), R*sin(theta), cos(3*theta)], theta = 0 .. 2*Pi, color = red, thickness = 4, linestyle = solid):

C := plots[spacecurve]([R*cos(theta), R*sin(theta), 0], theta = 0 .. 2*Pi, color = blue, thickness = 3, linestyle = solid):

plots[display](A, B, C, axes = normal, tickmarks = [3, 3, 3], view = [-1.7 .. 1.7, -1.7 .. 1.7, -1.7 .. 1.7], scaling = constrained);

without any equations:

plots[display](plottools[sphere]([0, 0, 0], 1));

Example:

R:=3: x0:=3: y0:=-1:  # Parameters of the circle

Circle:=plot([R*cos(t)+x0,R*sin(t)+y0, t=0..2*Pi], color=blue, thickness=2):

Data:=convert(op([1,1], plot(cos(theta), theta=0..2*Pi)), listlist):

Cosine:=plot(select(t->is((t[1]-x0)^2+(t[2]-y0)^2<=R^2), Data), color=red, thickness=3):

plots[display](Circle,Cosine, view=[min(0,x0-R)..x0+R,y0-R..y0+R], scaling=constrained);

Addition: By varying the parameters of the circle, you can get any circles. I do not understand the exact meaning of the phrase "The axis theta of the ploted function is at a radius R" 

Expression  e^x  should be coded as  exp(x)  or use  Expression  palette (in 2D Math of Standard GUI) to make it look in the usual form.  When you just type  the letter e  for Maple it just is a symbol rather than the number  e=2.7...

plots[textplot]([0, 0, "Hello"], color = green, font = [TIMES, ROMAN, 100], axes = none);

Another way - use for dummy variable any special symbol that distinguishes its special status, for example

 z := Int(f(t - _s),  _s=0..1);

You have to put the delimiters after each line (colon or semicolon), for example:

ma[1] := [-885.880598855072776, [bh = 0., g0h = 0., g1h = 0.825946224722250e-4]]:

ma[2] := [-877.957885609114328, [bh = 347.116836805625, g0h = 0., g1h = 0.164861392564e-3]]:

ma[3] := [-863.445203144006655, [bh = 0., g0h = 0., g1h = 0.787090377403668e-4]]:

aver := [bh = 121.477814540743, g0h = 0.249071340242633e-5, g1h = 0.110740782334817e-3]:

add((aver[1]-ma[j][2][1])^2, j = 1 .. 3);

You need to download commands in textual form, but not in the form of pictures, as requires a lot of time for retyping of data. Therefore, I present the solution for other data:

restart;

X:=Vector([$ 1..5]):

Y:=Vector([1.2, 3.8, 9.1, 15.7, 24.9]):

R:=unapply(Statistics[PowerFit](X, Y, t), t);

E:=add((Y[i]-R(X[i]))^2, i=1..5);  # Total Error

A:=plot(op(map(convert,[X,Y], list)), color=red, style=point, symbolsize=20):

B:=plot(R(x), x=0..5.7, color=blue, thickness=2):

plots[display](A,B);  # Visualization