with(Typesetting):
interface(typesetting=extended):

Suppress(g(t)):

diff(g(t),t) will then appear as the letter g with an overdot, and no independent variable showing.

The Suppress command is part of the Typesetting package. The difference between Suppress and declare is that with Suppress, the independent variable can be omitted on input as well as on output. Thus, diff(g,t) will then appear as g with an overdot.

RJL Maplesoft

There are commands in the Student VectorCalculus package that make the task a bit less tedious.

with(Student:-VectorCalculus):

V:=Vector([3-3*cos(theta),theta],coords=polar);
R:=PositionVector(convert(V,list),coords=polar);
T:=TangentLine(V,theta=3*Pi/4);
q1:=PlotPositionVector(T,x=-8..2):
q2:=PlotPositionVector(R,theta=0..2*Pi):
plots:-display(q1,q2,scaling=constrained);

RJL Maplesoft

Control Enter will put a visible page break at the point where the cursor is.

RJL Maplesoft

Four equations in two unknowns. I suspect that there were more than just syntax problems here.

RJL Maplesoft

Square brackets in Maple denote lists. They should not be used as replacements for parentheses. Change "[" to "(" and "]" to ")" in the definitions of the ODEs.

RJL Maplesoft

The code for the animation resides in the button Animation 2. Unfortunately, if you are viewing the example on the web site, you can't access the code. Here's the essence of the code:

with(plots):
with(plottools):
with(VectorCalculus):
q := plot(x^2, x = 0 .. 1, filled = true):
F := transform((x,y)->[x,0,y]):
Q := plots:-display(F(q)):
V := RootedVector(root=[2,0,0],[0,0,1]):
A := PlotVector(V,color=black):
p := display([seq(rotate(Q, (2*Pi*(1/30))*k, [[2, 0, 0], [2, 0, 1]]), k = 0 .. 30)], insequence = true):
spin := display([A, p]):

p4 := translate(animate(plot3d,[[r,t,(r-2)^2],r=1..2,t=-Pi..x,coords=cylindrical,filled],x=-Pi..Pi, paraminfo=false,frames=31),2,0,0):
display([p4,spin],labels=[x,z,y],tickmarks=[4,[0],2], orientation=[-55,70], axes=frame,scaling=constrained);

The variable q contains a graph of the region to be rotated, but it lies in the xy-plane.

The function F changes the plot data structure q so that the y-height becomes the z-height, and the y-coordinate is set to zero.

Q is then the plot data structure for the transformed region q.

V  is the arrow used to represent the axis of rotation.

A is a graph of the arrow V.

The animation of the rotation of Q about V is given the name p. This animation has 31 frames, each of which is obtained by applying the rotate command to the image in Q.

When the animation p is joined to A, the graph of the arrow V, it is called "spin".

The animation p4 uses cylindrical coordinates to draw the ever-expanding surface of the solid of revolution. However, this animation has to be translated so its vertical axis coincides with the vector V. This is done with the translate command.

The final display joins the animation p4 with the animation "spin". The result is the given region rotated about the axis x=2, dragging along the surface of revolution generated as the region rotates.

This is not the most efficient code, and a worksheet containing all these frames is slow to load. The animation generated by Carl Love's code is less resource-intensive.

RJL Maplesoft

Perhaps the reference is to the ODE Analyzer Assistant, an interactive assistant that can be accessed from the Tools/Assistants menu, or via the command dsolve[interactive]().

Of course, the argument to this command could be the ODE, in which case the Assistant launches with the ODE already in it. Alternatively, first write the ODE, then use the Context Menu option Solve DE Interactively, to launch the Assistant with the ODE already in it.

In either case, this Assistant has been part of Maple for a number of releases, including Maple 17

RJL Maplesoft

In the PlotPositionVector command, the option "normal" plots the normal field in the direction of the principal normal, which, in the example given, is towards the center of curvature. There is no control within this command on the direction of this field, so, create the principal normal field, negate it, and add it to the PlotPositionVector command as a vectorfield option. The whole calculation would be something like

with(Student[VectorCalculus]):
R1:=PositionVector([p,p^2],polar[r,t]);
N:=PrincipalNormal(R1,normalized);
NN:=VectorField(ConvertVector(N,free));
PlotPositionVector(R1,p=1..2,vectorfield=-NN,points=[1.5]);

RJL Maplesoft

In Document mode, using 2D math, type f(x)=2x, then use the Context Menu option "Assign Function".

The function f will be assigned, no pop-ups, no need to make setting changes, no syntax issues.

RJL Maplesoft

Tools->Tasks->Browse

Calculus-Differential->Applications->Tangent Line

This tools will detail the calculation of the tangent line, and also draw a graph of the function and its tangent line.

RJL Maplesoft

S:=[A,B,C];

print~(S)[];

The empty list at the end of the print~ command suppresses the printing of an empty list at the end of the print job.

RJL Maplesoft

Use colors and the legend option to distinguish different curves. For example,

plot([x,x^2],x=0..1,color=[black,red],legend=[typeset(x),typeset(x^2)]);

RJL Maplesoft

For each value of b>0 the first three boundary conditions can be satisfied. Write a procedure that takes in a value for b, and returns the solution f(b) that satisfies the ODE and the first 3 boundary conditions. Then, find b for which the last condition is satisfied.

Here's the code I put together to see if this problem has a solution.

Eq:= diff(f(y),y$3)+f(y)*diff(f(y),y$2)-diff(f(y),y$1)^2-(diff(f(y),y$1)+y/2*diff(f(y),y$2))=0;

R:=proc(b)

local bc,Q,F;

bc:=D(f)(0)=1,f(0)=0,(D@@2)(f)(b)=0;

Q:=dsolve({Eq,bc},f(y),numeric,output=listprocedure);

F:=rhs(Q[2]);

F(b);

end:

C:=x->x/2;

plot([R,C],.1..2);

The graphs of C and R intersect near b=1.5. I leave it to you to figure out how to solve the equation C(b)=R(b) numerically.

RJL Maplesoft

Since the feasible region is determined by linear inequalities, you can use the Linear Inequalities tutor in the Student Precalculus package. Simply access it through the Tools/Tutors/Precalculus menu. It launches with six default inequalities. Change the first four to the inequalities in your system, and uncheck the checkboxes for the last two.

At the bottom of the tutor the underlying command is displayed. It can be copied and pasted into a worksheet for modification/execution. The underlying command is "inequal" in the plots package.

Here's one version of the command after modifying the size of the bounding box and the colors. I think the labeldirections option can be deleted.

plots[inequal]({0 < x, 0 < y, x < 1, y < 1-x}, x = 0 .. 1, y = 0 .. 1, 'optionsexcluded' = ['color' = red], 'optionsfeasible' = ['color' = green], 'labels' = [x, y], 'labeldirections' = [HORIZONTAL, HORIZONTAL], 'axes' = NORMAL, 'scaling' = unconstrained)

Finally, here's a version of the implicitplot command that will also draw the feasible region.

plots:-implicitplot([x >= 0, x <= 1, y >= 0, y <= 1-x], x = 0 .. 1, y = 0 .. 1-x, filledregions = true)

RJL Maplesoft

Look at the recorded solution here:

http://www.maplesoft.com/teachingconcepts/detail.aspx?cid=9

RJL Maplesoft